vs_2_0
dcl_position	v0
dcl_normal		v1
dcl_color		v2
dcl_texcoord0	v3
dcl_texcoord6	v14
dcl_texcoord7	v15
dcl_tangent	v7
dcl_binormal	v8
dcl_texcoord4	v9
#include "../../VertexShader.h"

;------------------------------------------------------------------------------
; Geometry transform
;------------------------------------------------------------------------------

; Calculate bone indices 
mad		r7, vIndices, c23.x, c23.y

; Initialize w-coordinate
mov		r0.w, C_ONE

; Calculate the second bone weight from the first
sub		r8.x, C_ONE, vWeights.x

; Skin position by bone 0
MOVA	a0.x, r7.x
m4x3	r0.xyz, vPos, c[a0.x]
mul		pPos, r0, vWeights.x

; Skin position by bone 1
MOVA	a0.x, r7.y
m4x3	r0.xyz, vPos, c[a0.x]
mad		pPos, r0, r8.x, pPos

; Skin normal by bone 0
MOVA	a0.x, r7.x
m3x3	pNormal.xyz, vNormal, c[a0.x]
NormalizeVector(pNormal)

; Skin basis u by bone 0
m3x3	pBasisU.xyz, vBasisU, c[a0.x]
NormalizeVector(pBasisU)

; Skin basis v by bone 0
m3x3	pBasisV.xyz, vBasisV, c[a0.x]
NormalizeVector(pBasisV)

; Transform skinned position to projection space
m4x4	OPOS, pPos, C_PROJECTION_MATRIX
FIXUP_OPOS
#include "..\..\VertexShader.h"

;------------------------------------------------------------------------------
; Diffuse color
;------------------------------------------------------------------------------

; Combine vertex color and material color
mul		oD0, vDiffuse, C_MATERIAL_COLOR
#include "..\..\VertexShader.h"

;------------------------------------------------------------------------------
; Fog calculation
;------------------------------------------------------------------------------
#include "..\..\VertexShader.h"

;------------------------------------------------------------------------------
; Defines
;------------------------------------------------------------------------------

#define C_BASIS_TRANSFORM_1		c10
#define C_BASIS_TRANSFORM_2		c11
#define C_BASIS_TRANSFORM_3		c12

#define C_EYE_TRANSFORM_1		c13
#define C_EYE_TRANSFORM_2		c14
#define C_EYE_TRANSFORM_3		c15


;------------------------------------------------------------------------------
; Texture coordinates
;------------------------------------------------------------------------------

; Base texture is the normal map
mul		r0, vTexCoords, C_TEXCOORD_DECOMPRESS
add		oT0.x, r0.x, C_BASIS_TRANSFORM_1.w
add		oT0.y, r0.y, C_BASIS_TRANSFORM_2.w

; Rotate the basis vectors into cubemap space
dp3		oT1.x, pBasisU, C_BASIS_TRANSFORM_1
dp3		oT1.y, pBasisV, C_BASIS_TRANSFORM_1
dp3		oT1.z, pNormal, C_BASIS_TRANSFORM_1

dp3		oT2.x, pBasisU, C_BASIS_TRANSFORM_2
dp3		oT2.y, pBasisV, C_BASIS_TRANSFORM_2
dp3		oT2.z, pNormal, C_BASIS_TRANSFORM_2

dp3		oT3.x, pBasisU, C_BASIS_TRANSFORM_3
dp3		oT3.y, pBasisV, C_BASIS_TRANSFORM_3
dp3		oT3.z, pNormal, C_BASIS_TRANSFORM_3

; Store the eye vector in the texture coordinate w for the pixel shader
dp4		oT1.w, pPos, C_EYE_TRANSFORM_1
dp4		oT2.w, pPos, C_EYE_TRANSFORM_2
dp4		oT3.w, pPos, C_EYE_TRANSFORM_3